# Maintainer (aur): Roshless <pkg@roshless.com>
# Maintainer: Iván Ávalos <avalos@disroot.org>
# Contributor: bill-auger <bill-auger@programmer.net>
# Contributor: Wael Karram <wael@waelk.tech>


# parabola changes and rationale:
# - define the 'url' as the actual project website, rather than its forge
# - delete vendored libs - use system libs instead
# - verify source-ball signature


pkgname=lagrange
pkgrel=1
pkgver=1.19.4
pkgdesc="Beautiful Gemini Client"
url="https://gmi.skyjake.fi/lagrange/"
arch=('x86_64' 'i686' 'aarch64' 'armv7h')
license=("BSD-2-Clause")
source=(https://git.skyjake.fi/gemini/lagrange/releases/download/v$pkgver/lagrange-$pkgver.tar.gz{,.sig})

depends=(
    "fribidi"
    "harfbuzz"
    "hicolor-icon-theme"
    "libunistring"
    "openssl"
    "pcre"
    "sdl2"
    "zlib"
    "mpg123"
)
makedepends=(
    "cmake"
    "zip"
)
optdepends=(
    "libwebp: Webp decode support"
    "libjxl: JPEG XL image decoding"
)


prepare() {
  cd "$srcdir"/$pkgname-$pkgver/

  # delete vendored libs - use system libs instead
  rm -rf lib/fribidi/
  rm -rf lib/harfbuzz/
}

build() {
    cmake -B build -S "$pkgname-$pkgver" \
        -DCMAKE_INSTALL_PREFIX='/usr' \
        -DENABLE_KERNING=OFF \
        -DTFDN_ENABLE_WARN_ERROR=OFF \
        -DENABLE_FRIBIDI_BUILD=OFF \
        -DENABLE_HARFBUZZ_MINIMAL=OFF \
        -Wno-dev
    make -C build
}

package() {
    install -Dm644 $pkgname-$pkgver/LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

    cd build
    make DESTDIR="$pkgdir" install
}

sha256sums=('a51e7519f0dfa2cfc2918d6b498a6aca6a966702ae0f8d2c94f02f4287b2ffd7' 'SKIP')
validpgpkeys=('15674AE498667047A3EB9431BACCFCFB98DB2EDC') # Jaakko Keränen
