# Copyright (C) 2022,2025-2026 Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.

pkgname=gnuboot-manual
_pkgname=gnuboot
# hyphens are not supported in versions so we can't do -RC6. This is also why
# we can't use pkgver() { } and git describe to compute the version.
pkgver=0.1
pkgrel=4
pkgdesc="GNU Boot manual. It also explains how to authenticate GNU Boot."
arch=('armv7h' 'i686' 'x86_64')
license=('GFDL-1.3-or-later'
         'GPL-3.0-or-later')
makedepends=('autoconf'
             'automake'
             'coreutils'
             'gawk'
             'git'
             'graphicsmagick'
             'grep'
             'guix'
             'libtool'
             'pkg-config'
             'texinfo'
             'texlive-latexrecommended'
             'texlive-plaingeneric')
_commit=('496ad2f7a4ddcbdf21c4551bab3543f608a6afb5')
source=("git+https://git.savannah.gnu.org/git/gnuboot.git#commit=${_commit}")
sha512sums=('SKIP')

build() {
  cd "${srcdir}/${_pkgname}"
  ./autogen.sh
  ./configure --prefix=/usr --disable-kvm
  make manuals
}

package() {
  cd "${srcdir}/${_pkgname}"
  make DESTDIR="$pkgdir" install
}
