# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
# Maintainer (aur): Stefan Majewsky <majewsky@gmx.net>

pkgname='art'
pkgver=2.0.1.r6.gbd950e6
_commit=bd950e6c9c3f37bbf91b4403f1066efa4caef1bb
pkgrel=1
pkgdesc='Arch Repository building Tool'
arch=('i686' 'x86_64' 'armv7h')
url='https://github.com/majewsky/art'
license=('GPL-3.0-or-later')
depends=('pacman') # for makepkg, repo-add, repo-remove (also satisfies dependencies on xz and gpg)
optdepends=(
    'holo-build: to build packages from *.pkg.toml files'
)
makedepends=('go' 'git')
source=("git+https://github.com/majewsky/${pkgname}.git#commit=${_commit}")
sha256sums=('65ed5c0c4444da469b3747fe56199d2c51be396503815965e66919273f08c203')

pkgver() {
    cd "${srcdir}/${pkgname}"
    git describe --long --tags | sed -E 's/^v(.*)-([0-9]+)-g/\1.r\2.g/'
}

prepare() {
    cd "${srcdir}/${pkgname}"
    sed -i 's/^GO_BUILDFLAGS\s*=.*/& -trimpath/' Makefile
}

build() {
    cd "${srcdir}/${pkgname}"
    make
}

package() {
    cd "${srcdir}/${pkgname}"
    make install DESTDIR="${pkgdir}"
}
